Apple Color Plotter: Business BASIC Chart Maker III (4 of 5)

Apple Color Plotter: Business BASIC Chart Maker III (4 of 5)

9007 pv=21:ph=64:sl=1:GOSUB 101:
     IF a$=CHR$(27) THEN GOSUB 72:RETURN
9008 IF b$="Y" OR b$="y" THEN border$="Y":GOTO 9017
9009 IF b$="N" OR b$="n" THEN border$="N":GOTO 9017
9010 GOTO 9007
9017 GOSUB 50000:IF cmd=27 THEN GOSUB 72:RETURN
9018 ON KBD GOTO 9900
9019 pv=20:m$="Press ESCAPE to Terminate Plotting":GOSUB 353
9020 IF border$="Y" THEN xp=0:
     yp=0:GOSUB 51110:yp=1759:GOSUB 51111:xp=2394:GOSUB 51111:
     yp=0:GOSUB 51111:xp=0:GOSUB 51111
9030 FOR i=1 TO 10
9040 IF LEN(txt$(i))=0 THEN 9400
9050 IF size(i)=1 THEN si=54:si1=54:GOTO 9060
9051 IF size(i)=2 THEN si=72:si1=36:GOTO 9060
9052 IF size(i)=3 THEN si=108:si1=27
9060 GOSUB 51150
9070 pn=color(i):GOSUB 51100
9072 hpgl$="SL0":IF sl$(i)="Y" THEN hpgl$="SL20"
9076 GOSUB 51000
9080 REM *** xp=100:yp=1759-(i*175.9):yp=yp+(si/2):GOSUB 51110
9085 xp=100:yp=1659-(i*155.9):yp=yp+si1:GOSUB 51110
9090 IF center$(i)="Y" THEN xp=1197:GOSUB 51110:GOSUB 9500:
     GOTO 9110
9100 IF dent(i)>0 THEN GOSUB 9600
9110 ms$=txt$(i):GOSUB 51140
9120 IF bold$(i)<>"Y" THEN GOTO 9400
9130 IF center$(i)="Y" THEN xp=1197:GOSUB 51110:GOSUB 9500:
     GOTO 9300
9200 xp=100:GOSUB 51110
9210 IF dent(i)>0 THEN GOSUB 9600
9300 hpgl$="MR4,4":GOSUB 51000
9310 ms$=txt$(i):GOSUB 51140
9400 NEXT
9410 pn=1:GOSUB 51100
9415 IF LEN(chart$)>0 THEN si=40:GOSUB 51150:xp=2050:yp=10:
     GOSUB 51110:ms$=chart$:GOSUB 51140
9420 si=30:GOSUB 51150
9430 hpgl$="CH":GOSUB 51000:pn=1:GOSUB 51100
9440 CLOSE:GOSUB 72
9450 IF exit=1 THEN exit=0:GOTO 1200
9499 RETURN
9500 BACKUP=((INT(LEN(txt$(i))/2)))
9510 IF backup<.5 THEN GOTO 9550
9515 hpgl$="PL ":GOSUB 51000:hpgl$="PL"+CHR$(8):GOSUB 51000
9520 FOR j9=1 TO backup
9530 hpgl$="PL"+CHR$(8):GOSUB 51000
9540 NEXT
9550 RETURN
9600 FOR j9=1 TO dent(i)
9610 hpgl$="PL ":GOSUB 51000
9620 NEXT:RETURN
9900 OFF KBD
9910 IF KBD=27 THEN 9940
9920 ON KBD GOTO 9900
9930 RETURN
9940 ON ERR GOTO 9960
9950 POP:POP:POP:POP:POP:POP:POP:POP:POP:POP:POP:POP:POP:POP:
     POP:POP:POP:POP:POP:POP:POP:POP:POP:POP:POP:POP:POP:POP:
     POP:POP:POP:POP
9960 exit=1
9999 GOTO 9410
10000 GOSUB 71:m$="Move a Line":GOSUB 357
10010 pv=20:ph=5:m$="Move from line # :  Move to line :":
      GOSUB 353
10020 ph=39:sl=2:ll=1:ul=10:GOSUB 201:IF a$=CHR$(27) THEN 10199
10030 ON x9 GOTO 10040,10050
10040 GOSUB 369:GOTO 10020
10050 n2=x8
10060 ph=59:sl=2:ll=1:ul=10:GOSUB 201:IF a$=CHR$(27) THEN 10199
10070 ON x9 GOTO 10080,10090
10080 GOSUB 369:GOTO 10060
10090 n3=x8
10100 Txt$(n3)=Txt$(n2):center$(n3)=center$(n2):
      dent(n3)=dent(n2):size(n3)=size(n2):bold$(n3)=bold$(n2):
      color(n3)=color(n2):sl$(n3)=sl$(n2):i=n3:GOSUB 10800
10110 i=n2:GOSUB 10900:GOSUB 10800
10199 GOSUB 72:RETURN
10800 WINDOW 5,i+3 TO 79,i+3:GOSUB 90:GOSUB 7010:RETURN
10900 txt$(i)="":center$(i)="":dent(i)=0:size(i)=0:
      bold$(i)="":color(i)=0:sl$(i)="":RETURN
50000 PRINT CHR$(7);
50010 PV=17:PH=2:GOSUB 99:M$="Prepare the Plotter":GOSUB 350
50015 m$="(Insert Paper, turn it on, and press 'LOCAL' button)":
      pv=18:GOSUB 350
50020 PV=19:GOSUB 99:
      M$="Keyboard 'RETURN' When Ready to Start Plotting":
      GOSUB 350
50025 pv=21:
      m$="ESCAPE cancels Plot; 'C' Changes Driver Device Name":
      GOSUB 350
50030 GOSUB 400:IF cmd=27 THEN GOSUB 72:RETURN
50032 IF cmd=67 THEN GOSUB 57000:GOTO 50000
50033 IF a$<>CHR$(13) THEN 50030
50035 ON ERR GOTO 50050
50040 OPEN#1,plr$:hpgl$="SP0":GOSUB 51000:PN=1:GOSUB 51100
50041 GOSUB 73:pv=20:m$="Drawing Graph":GOSUB 350:GOSUB 72
50045 ON ERR GOTO 97
50047 RETURN
50049 PRINT ERR, ERRLIN:END
50050 PRINT CHR$(7);:GOSUB 73:GOSUB 71
50060 m$="Graph'n'Calc tried to Open '"+plr$+"' which is not":
      pv=17:GOSUB 350
50070 m$="configured into SOS.DRIVER on the 'Boot' Diskette.":
      pv=19:ph=5:GOSUB 352
50080 m$="If this driver is configured for the Plotter, give":
      pv=20:GOSUB 352
50090 m$="its Device Name in the 'C' option in the Draw":
      pv=21:GOSUB 352

Back